Настенные солнечные часы

Как сделать солнечные часы? Если вы задались этим вопросом, то, прочитав эту статью, вы их сделаете! Ниже представлен алгоритм действий, методика расчета в Excel и несколько общих рекомендаций по этой интересной теме. Приступим к делу, опустив общие теоретические аспекты, ...

В начале рискну дать два простых совета:

1. Если вы хотите сделать солнечные часы для квартиры, переносные в качестве сувенира, возможно, вместе с сыном, то, мне кажется, лучшее решение – горизонтальный циферблат.

Не советую делать наклонный циферблат – такие часы (экваториальные) менее практичны и более громоздки.

2. Если вы задумали сделать солнечные часы на даче, в частном доме, на предприятии, в населенном пункте, то лучшее, на мой взгляд, решение – вертикальный циферблат. Этот вариант нагляднее, не требует специально отдельной выделенной площадки, может быть гораздо дешевле в изготовлении и более защищен от вандалов.

Такие часы могут стать вашей визитной карточкой, если разместить их на воротах, стене или даже крыше. Именно о расчете таких часов и пойдет далее речь.

Представленный расчет в Excel, можно выполнить также в программе Calc из пакетов Apache OpenOffice или LibreOffice.

Расчет в Excel вертикальных солнечных часов.

Вся дальнейшая фразеология верна только для северного полушария!

Рассчитанные солнечные часы будут показывать обычное МЕСТНОЕ ВРЕМЯ!

Стену (поверхность) для установки часов следует выбрать южную, юго-восточную или юго-западную, так как северная стена в средних широтах почти не освещается солнцем. Можно, при необходимости, смонтировать установочную поверхность для циферблата под эстетичным и удобным для обозрения ракурсом на южном угле здания или столбе ворот. Правильный выбор места установки подскажет ваша фантазия и здравый смысл – место не должно затеняться деревьями и соседними постройками (по возможности).

Рассматриваемый пример расчета выполнен для города Омска (Россия) для установки часов на юго-восточной стене здания, развернутой в сторону востока на угол δ=24°.

Исходные данные:

1. Константу — угол наклона экватора к эклиптике ε в градусах вводим

в ячейку D3: 23,433

2. Часовой пояс (GMT) вашего населенного пункта N узнаем, например, через поисковик Google и вписываем в нашу расчетную программу

в D4: 6

Для определения следующих трех исходных данных рекомендую воспользоваться бесплатной замечательной программой Google Earth !

Скачиваете и устанавливаете программу на свой ПК, находите свой дом и выбранную стену, увеличиваете участок карты и печатаете на бумаге. Сетка параллелей и меридианов, присутствующая на карте, позволит вам с точностью до секунд определить координаты места установки солнечных часов, а транспортиром вы легко измерите угол разворота выбранной стены δ (смотри рисунок, расположенный выше).

Из практики – это самый точный, дешевый и простой способ определения исходных данных, хотя существует и несколько других способов, требующих измерений на местности.

3. Географическую широту места установки часов φ в градусах записываем

в D5: 55,061

4. Значение географической долготы λ в градусах заносим

в D6: 73,282

5. Угол разворота стены здания δ в градусах записываем

в D7: 24,000

6. Длину основания гномона (элемента часов, отбрасывающего тень на циферблат) AB в миллиметрах вписываем

в D8: 275

Размеры гномона зависят от размеров циферблата. Если солнечные часы имеют маленький циферблат, то и гномон должен быть небольшим. Выбирайте длину основания гномона, ориентируясь на длину его тени в полдень (смотри примечание к ячейке B8 в программе).

В примечаниях к записям в ячейках B 3… B 8 даны важные рекомендации! Ознакомьтесь с ними обязательно!!!

Результаты расчетов:

7. Угол установки основания гномона α в градусах вычисляем

в ячейке D10: =ATAN (TAN ((90-D5)/180*ПИ())*SIN (D7/180*ПИ()))/ПИ()*180 =15,863

α =arctg (tg (90- φ )*sin (δ ))

Правила отсчета угла установки основания гномона приведены в примечании к ячейке B 10.

8. Угол высоты гномона β в градусах определяем

в ячейке D11: =ASIN (SIN ((90-D5)/180*ПИ())*COS (D7/180*ПИ()))/ПИ()*180 =31,547

β =arcsin (sin (90- φ )*cos (δ ))

9. Высоту гномона BC в миллиметрах рассчитываем

в ячейке D12: =D8*TAN (D11/180* ПИ()) =169

BC = AB * tg (β )

10. Длину рабочей грани гномона AC в миллиметрах находим по теореме Пифагора

в D13: =(D8^2+D12^2)^0,5 =323

AC =(AB 2 + BC 2 ) 0,5

Длина рабочей грани может пригодиться, если гномон вы решите делать в виде наклонного стержня.

11. Длину тени AE в миллиметрах в астрономический полдень 20…21 июня вычисляем

в D14: =$D$8*COS ($D$10/180*ПИ())+$D$12*COS ($D$7/180*ПИ())/(TAN (($D$5-$D$3)/180*ПИ())) =515

AE = AB * cos (α )+ BC * cos (δ )/ tg (φ — ε )

12. Длину тени AE в миллиметрах в астрономический полдень 21…22 декабря считаем

в D15: =$D$8*COS ($D$10/180*ПИ())+$D$12*COS ($D$7/180*ПИ())/(TAN (($D$5+ $D$3)/180*ПИ())) =296

AE = AB * cos (α )+ BC * cos (δ )/ tg (φ + ε )

Длины теней рассчитаны для сопоставления и корректировки размеров гномона и циферблата.

13. Вспомогательный расчетный угол χ в градусах определяем

в D16: =ATAN (TAN (D10/180*ПИ())/SIN (D11/180*ПИ()))/ПИ()*180 =28,507

χ =arctg (tg (α )/sin (β ))

14. Поправку по долготе Δ λ в градусах вычисляем

в D17: =D4*15-D6 =16,718

Δ λ = N *15-λ

15. Угол, определяющий часовую линию на циферблате для 3-х часов γ 3 в градусах, вычисляем

в ячейке D18: =(ATAN (SIN ($D$11/180*ПИ())*TAN (($D$16-135-$D$17)/180*ПИ())) -$D$10/180*ПИ())/ПИ()*180 =22,769

γ 3 = arctg (sin (β )* tg (χ -135-Δ λ )) -α

Угол, определяющий часовую линию на циферблате для 4-х часов γ 4 в градусах, рассчитываем

в ячейке D19: =(ATAN (SIN ($D$11/180*ПИ())*TAN (($D$16-120-$D$17)/180*ПИ())) -$D$10/180*ПИ())/ПИ()*180 = 41,975

γ 4 = arctg (sin (β )* tg (χ -120-Δ λ )) -α

В полученном множестве решений в середине таблицы находим момент времени, когда значение угла γ i меняет знак. В нашем примере это происходит между 13 и 14 часами в астрономический полдень. Выбираем вверх по таблице все отрицательные значения больше -90° и вниз по таблице – все положительные значения меньше 90°. Эта область на снимке экрана с расчетом в Excel (смотри выше) выделена красной рамкой. Это и есть рабочие значения углов γ i от 6 до 17 часов, которые могут быть применены для создания циферблата.

Правила отсчета часовых углов γ i приведены в примечании к объединенным ячейкам B 10... B 36. Обратите внимание, что эти правила противоположны правилу отсчета угла α !

Расчет в Excel завершен. Можно изготовить солнечные часы и разместить на ранее выбранной стене. У нас для этого есть все необходимые данные.

Точность показаний солнечных часов.

Из-за эллиптичности орбиты Земли и наклона земной оси к плоскости движения (эклиптике) видимое перемещение Солнца по небесной сфере неравномерно ! Это означает, что солнечные часы в разные периоды года то бегут вперед, то отстают.

На рисунке чуть ниже изображен график уравнения времени, на котором показаны характерные точки.

Четыре зеленые точки показывают даты, когда солнечные часы идут абсолютно точно – это ~14 апреля, ~14 июня, ~2 сентября и ~24 декабря.

Четыре желтые точки – это дни равноденствий (~20 марта и ~22 сентября) и солнцестояний (~21 июня и ~21 декабря).

Две красные точки показывают дни максимальных ошибок в показаниях солнечных часов. Около ~11 февраля солнечные часы отстают на ~14 минут от показаний обычных, а ~2 ноября опережают обычные часы на ~16 минут.

Чтобы узнать точное время, например 1 августа, следует к показаниям солнечных часов добавить 6 минут в соответствии с графиком.

Обращаю внимание, что с 20 марта по 20 сентября (то есть — летом) ошибка в показаниях солнечных часов не превышает ±7 минут. Думаю, такая точность многих устроит и надобность применять поправки по графику уравнения времени будет излишней.

Как часы красиво оформить решите сами или обратитесь за помощью к художникам. В Сети можно найти сотни фотографий вертикальных солнечных часов, которые могут помочь вам в решении этого вопроса.

О расчете горизонтальных (переносных, сувенирных) солнечных часов речь пойдет в одной из очередных статей на блоге.

Прошу уважающих труд автора скачивать файл с примером после подписки на анонсы статей!

Введите Ваш e-mail:

Статьи с близкой тематикой

Отзывы

30 комментариев на «Настенные солнечные часы»

  1. Belmando 29 Апр 2015 02:40
  2. Александр 14 Сен 2015 22:45
  3. Александр Воробьев 15 Сен 2015 10:01
  4. Александр 15 Сен 2015 16:08
  5. Александр Воробьев 15 Сен 2015 20:24
  6. Александр Воробьев 15 Сен 2015 20:30
  7. Александр 16 Сен 2015 12:40
  8. Николай 03 Мар 2016 17:02
  9. Николай 03 Мар 2016 17:09
  10. Николай 03 Мар 2016 17:13
  11. Николай 03 Мар 2016 17:15
  12. Александр Воробьев 03 Мар 2016 19:57
  13. Николай 04 Мар 2016 10:42
  14. Николай 04 Мар 2016 10:49
  15. Николай 04 Мар 2016 11:23
  16. Александр Воробьев 05 Мар 2016 15:43
  17. Андрей 10 Авг 2016 13:13
  18. Константин 25 Авг 2016 13:07
  19. Александр Воробьев 25 Авг 2016 19:17
  20. Сергей 30 Июн 2017 11:56
  21. Александр Воробьев 01 Июл 2017 14:53
  22. Александр Воробьев 25 Июл 2017 19:53
  23. Сергей 14 Авг 2017 17:45
  24. Александр Воробьев 14 Авг 2017 19:04
  25. Анатолий 30 Окт 2017 05:38
  26. Александр Воробьев 30 Окт 2017 18:19
  27. Петр 01 Ноя 2017 13:24
  28. Александр Воробьев 01 Ноя 2017 20:22
  29. Петр 02 Ноя 2017 02:05
  30. Александр Воробьев 02 Ноя 2017 19:06

 

Возможно, будет полезно почитать: